[XaraXtreme-commits] Commit Complete

[subversion@xxxxxxxxxxxxxx]

Commit by  : luke
Repository : xara
Revision   : 1240
Date       : Fri Jun  2 14:42:25 BST 2006

Changed paths:
   A /Trunk/XaraLX/acinclude.m4 (from /Trunk/XaraLX/binreloc.m4:1239)
   M /Trunk/XaraLX/configure.in

Fix AM_BINRELOC warning


Diff:
Index: Trunk/XaraLX/configure.in
===================================================================
--- Trunk/XaraLX/configure.in	(revision 1239)
+++ Trunk/XaraLX/configure.in	(revision 1240)
@@ -2,10 +2,6 @@
 AC_CANONICAL_TARGET
 AM_INIT_AUTOMAKE(XaraLX, 0.5)
 
-dnl It's recomended to put this in acinclude.m4, but including it is 
-dnl more convienent
-builtin( include, binreloc.m4)
-
 AM_BINRELOC
 
 # Process command line arguments
@@ -154,7 +150,7 @@
 if test -n "$vers" && test "$vers" -ge 2006003; then
 	WX_CPPFLAGS="`$WXCONFIG --static=$StaticEnable --debug=$DebugEnable --unicode=yes --cppflags`"
 	WX_CXXFLAGS="`$WXCONFIG --static=$StaticEnable --debug=$DebugEnable --unicode=yes --cxxflags | sed -e 's/-fno-exceptions//'`"
-	WX_LIBS="`$WXCONFIG --static=$StaticEnable --debug=$DebugEnable --unicode=yes --libs`"
+	WX_LIBS="`$WXCONFIG --static=$StaticEnable --debug=$DebugEnable --unicode=yes --libs std,media`"
 
 	# See if we are running on GTK
 	WX_GTK="no"
Index: Trunk/XaraLX/acinclude.m4
===================================================================
--- Trunk/XaraLX/acinclude.m4	(revision 0)
+++ Trunk/XaraLX/acinclude.m4	(revision 1240)
@@ -0,0 +1,77 @@
+# Check for binary relocation support.
+# Written by Hongli Lai
+# http://autopackage.org/
+
+AC_DEFUN([AM_BINRELOC],
+[
+	AC_ARG_ENABLE(binreloc,
+		[  --enable-binreloc       compile with binary relocation support
+                          (default=enable when available)],
+		enable_binreloc=$enableval,enable_binreloc=auto)
+
+	AC_ARG_ENABLE(binreloc-threads,
+		[  --enable-binreloc-threads      compile binary relocation with threads support
+	                         (default=yes)],
+		enable_binreloc_threads=$enableval,enable_binreloc_threads=yes)
+
+	BINRELOC_CFLAGS=
+	BINRELOC_LIBS=
+	if test "x$enable_binreloc" = "xauto"; then
+		AC_CHECK_FILE([/proc/self/maps])
+		AC_CACHE_CHECK([whether everything is installed to the same prefix],
+			       [br_cv_valid_prefixes], [
+				if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
+					"$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
+					"$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
+				then
+					br_cv_valid_prefixes=yes
+				else
+					br_cv_valid_prefixes=no
+				fi
+				])
+	fi
+	AC_CACHE_CHECK([whether binary relocation support should be enabled],
+		       [br_cv_binreloc],
+		       [if test "x$enable_binreloc" = "xyes"; then
+		       	       br_cv_binreloc=yes
+		       elif test "x$enable_binreloc" = "xauto"; then
+			       if test "x$br_cv_valid_prefixes" = "xyes" -a \
+			       	       "x$ac_cv_file__proc_self_maps" = "xyes"; then
+				       br_cv_binreloc=yes
+			       else
+				       br_cv_binreloc=no
+			       fi
+		       else
+			       br_cv_binreloc=no
+		       fi])
+
+	if test "x$br_cv_binreloc" = "xyes"; then
+		BINRELOC_CFLAGS="-DENABLE_BINRELOC"
+		AC_DEFINE(ENABLE_BINRELOC,,[Use binary relocation?])
+		if test "x$enable_binreloc_threads" = "xyes"; then
+			AC_CHECK_LIB([pthread], [pthread_getspecific])
+		fi
+
+		AC_CACHE_CHECK([whether binary relocation should use threads],
+			       [br_cv_binreloc_threads],
+			       [if test "x$enable_binreloc_threads" = "xyes"; then
+					if test "x$ac_cv_lib_pthread_pthread_getspecific" = "xyes"; then
+						br_cv_binreloc_threads=yes
+					else
+						br_cv_binreloc_threads=no
+					fi
+			        else
+					br_cv_binreloc_threads=no
+				fi])
+
+		if test "x$br_cv_binreloc_threads" = "xyes"; then
+			BINRELOC_LIBS="-lpthread"
+			AC_DEFINE(BR_PTHREAD,1,[Include pthread support for binary relocation?])
+		else
+			BINRELOC_CFLAGS="$BINRELOC_CFLAGS -DBR_PTHREADS=0"
+			AC_DEFINE(BR_PTHREAD,0,[Include pthread support for binary relocation?])
+		fi
+	fi
+	AC_SUBST(BINRELOC_CFLAGS)
+	AC_SUBST(BINRELOC_LIBS)
+])


Xara